Posted: Mon Dec 08, 2008 11:37 am Post subject: FTP JCL to JES for processing
Here is my problem. We intend for users to be able to run their own batch reports via FTP from their PC.
The idea is to use a language that allows them to, without knowing, construct their own JCL for the Cobol or EzTreve report, with whatever parameters they need, like date ranges, and the application constuct the JCL with the parameters in the correct position.
Once they exit the application it can then FTP the JCL using 'quote site filetype=jes' to let the mainframe know it's to go to the JES.
Now the question...
What application would work best. ASP.NET, VB, other??, or can this be done with the Microsoft tools that come with most PCs?
Joined: 03 Jan 2003 Posts: 1014 Topics: 13 Location: Atlantis
Posted: Mon Dec 08, 2008 6:38 pm Post subject:
Any tools should do. You can use a simple bat (or .cmd) file from windows.
The problem is that the user's password must be stored somewhere on the disk and that may be a security issue. For example, if you use a .cmd file like
Code:
@echo off
rem submit a job and display the output
rem Parameters: user password jclfile
(
echo open your.mvs.ip.address
echo user %1 %2
echo ascii
echo quote site filetype=jes
echo put %3
echo quit
) >f1
ftp -n -s:f1 |find "It is known to JES as" >f2
FOR /F "usebackq tokens=7" %%i IN (`type f2`) DO set jobname=%%i
(
echo open your.mvs.ip.address
echo user %1 %2
echo ascii
echo quote site filetype=jes
echo get %jobname%
echo quit
) | ftp -n >nul
del f1
type %jobname%
you still need to pass in the userid and password and those need to be stored somewhere. In this case, it is also stored in a temporary file which, although deleted, will still be recoverable from the disk (of course you an use something like sdelete to wipe it off though)
Obviously, this example is NOT an industrial strength solution since there is no error checking anywhere, but it should illustrate the simplicity of invoking FTP from anywhere if you want to use the built in (windows) version. _________________ New members are encouraged to read the How To Ask Questions The Smart Way FAQ at http://www.catb.org/~esr/faqs/smart-questions.html.
You cannot post new topics in this forum You cannot reply to topics in this forum You cannot edit your posts in this forum You cannot delete your posts in this forum You cannot vote in polls in this forum
FAQ
Search
Quick Manuals
Register
Profile
Log in to check your private messages
Log in
